simulating an LM431

This is the place for any magazine-related discussions that don't fit in any of the column discussion boards below.
Post Reply
Dimbulb
Posts: 324
Joined: Sun Oct 13, 2002 1:01 am

simulating an LM431

Post by Dimbulb » Sun Dec 11, 2005 11:16 am

I am using multisim (electronic workbench)
and would like to simulate an LM431.
Would anyone have a working example I could
try ? Thanks

Ron H
Posts: 360
Joined: Tue Dec 18, 2001 1:01 am
Location: Boise, ID
Contact:

Re: simulating an LM431

Post by Ron H » Mon Dec 12, 2005 6:58 pm

.subckt TL431 REFIN ANODE CATHODE
Q8 Q2_C Q2_C R4_N 0 P1
Q9 CATHODE Q7_C Q9_E 0 n1
R8 Q4_E ANODE 800
R9 Q2_E R9_N 4k
Q10 CATHODE R6_P ANODE 0 n1 5
Q11 Q7_C R10_P ANODE 0 n1
*.nodeset R3_N 1
C2 R9_N C2_N 20p
R10 R10_P R1_N 1k
C1 CATHODE Q7_C 20p
D1 ANODE Q7_C DIODE
D2 ANODE CATHODE DIODE
R4 CATHODE R4_N 800
Q2 Q2_C Q1_E Q2_E 0 n1
Q3 R9_N C2_N ANODE 0 n1
R5 CATHODE R5_N 800
R6 R6_P Q9_E 150
Q1 CATHODE REFIN Q1_E 0 n1
R7 ANODE R6_P 10k
Q6 Q7_C Q7_C REFIN 0 n1
Q7 Q7_C Q2_C R5_N 0 P1
R1 R3_N R1_N 2.4k
R2 R3_N C2_N 7.2k
Q4 C2_N R1_N Q4_E 0 n1
Q5 R1_N R1_N ANODE 0 n1
R3 Q1_E R3_N 3.28k
.model p1 pnp bf=50
.model n1 npn bf=100 tf=2n cjc=1p is=5e-18 NF=1.07
.model diode d rs=1 cjo=2p
.ends

Dimbulb
Posts: 324
Joined: Sun Oct 13, 2002 1:01 am

Re: simulating an LM431

Post by Dimbulb » Mon Dec 12, 2005 8:33 pm

Thanks, I made a copy of LM117 and replaced the model data with your model data and remamed it LM431. I will try it out as time allows.
thanks for your help!

Ron H
Posts: 360
Joined: Tue Dec 18, 2001 1:01 am
Location: Boise, ID
Contact:

Re: simulating an LM431

Post by Ron H » Tue Dec 13, 2005 8:44 pm

Note that the subcircuit is called TL431, not LM431. You can change it in the file if you want.

Post Reply

Who is online

Users browsing this forum: Google [Bot] and 29 guests